Глава 38. Объектно-ориентированное программирование

Примеры
	Глава 38. Объектно-ориентированное программирование

Примеры

Животные

В соответствии с описанной выше идеологией, попробуем создать программу, демонстрирующую класс животных. Изготовим несколько животных и заставим их проявить свои умения, для чего предварительно их этими умениями оснастим.

Набор умений будет достаточно скромным. Животное может назвать себя и подать голос (процедура say). Конечно, объект «животное» должен содержать соответствующую информацию. Её разумно закладывать в каждое животное на этапе создания:

Perl
my $cat=Animal->new('Кошка', 'Мяу');
my $dog=Animal->new('Собака', 'Гав');
my $pig=Animal->new('Свинья', 'Хрю');
my $ram=Animal->new('Баран', 'Бее');
my $cow=Animal->new('Корова', 'Муу');
my $horse=Animal->new('Лошадь', 'И-го-го';)

после чего готовые к употреблению животные могут представиться:

Perl
$cat->say;
$dog->say;
$pig->say;
$ram->say;
$cow->say;
$horse->say;

На экране при этом должно появиться:

Здравствуйте, я Кошка. Мяу!
Здравствуйте, я Собака. Гав!
Здравствуйте, я Свинья. Хрю!
Здравствуйте, я Баран. Бее!
Здравствуйте, я Корова. Муу!
Здравствуйте, я Лошадь. И-го-го!

Первым делом необходимо обозначить, что все определяемые процедуры относятся к классу животных. Для этого поместим в программу команду package Animal;. Процедура new предназначена для создания новых животных; это так называемый конструктор объектов. Эта процедура должна получить в качестве параметра название класса (Animal). Второй и третий параметры, получаемые процедурой new, это название каждого конкретного животного, и звук, издаваемый им. Эти данные помещаются соответственно в поля name и sound безымянного ассоциативного массива, ссылка на который помещается в переменную $self. Эта ссылка и есть животное. Команда bless (встроенная в Perl) помечает, что это не просто ссылка на хэш, а объект класса Animal. Никаких других действий bless не совершает, только возвращает ссылку с пометкой, после чего та возвращается из конструктора оператором return.

Perl
package Animal;

sub new
{
	my $class=shift;
	my $self={name=>shift, sound=>shift};
	return bless $self, $class;
}

Следующая наша задача — определение процедуры say. Определение совсем простое:

Perl
sub say
{
	my $self=shift;
	print "Здравствуйте, я $self->{name}. $self->{sound}!\n";
}

На этом определение класса Animal завершено. При желании наших животных можно снабдить и другими навыками. Тут чувствуешь себя Творцом!

Позволим животным проявить себя. Но прежде нужно указать, что определение класса животных закончилось и далее идёт основная часть программы. Для этого помещаем команду

Perl
package main;

Класс main который подразумевается, если явным образом не указан другой. Поскольку другой в нашем случае указан, это строчка необходима.

Perl
package main;

my $cat=Animal->new('Кошка', 'Мяу');
my $dog=Animal->new('Собака', 'Гав');
my $pig=Animal->new('Свинья', 'Хрю');
my $ram=Animal->new('Баран', 'Бее');
my $cow=Animal->new('Корова', 'Муу');
my $horse=Animal->new('Лошадь', 'И-го-го');

$_->say for $cat, $dog, $pig, $ram, $cow, $horse;