Поскольку программа будет содержать сообщения на русском языке, включим режим UTF-8 и позаботимся о соответствующих настройках стандартных дескрипторов:

Perl
use utf8;
use open qw/:locale/;

Затем подключим нужные модули. Для создания графического файла потребуется знакомый нам по главе 47. «Трассировка растровых изображений» модуль Image::Magick, а для обработки опций в командной строке — модуль Getopt::Long:

Perl
use Image::Magick;
use Getopt::Long qw/:config no_ignore_case bundling/;

Предусмотрим в программе возможность задания в командной строке следующих опций:

Для значений опций объявим переменные $outputFile, $region, $density, $radius и присвоим им значения по умолчанию. Кроме того, определим процедуру help, которая печатает подсказку:

Perl
my $radius=100;
my $outputFile='Mandelbrot.png';
my $region='-2.4:-1.2:.8:1.2';
my $density=400;

sub help()
{
	STDERR->print(<<__HELP__);
mandelbrot.pl ⟨опции⟩

⟨опции⟩:
	-o, --output-file ⟨имя графического файла⟩
		имя выходного файла («$outputFile»)
	-r, --region ⟨umin⟩:⟨vmin⟩:⟨umax⟩:⟨vmax⟩
		прямоугольник на комплексной плоскости ($region)
	-d, --density ⟨целое число⟩
		количество пикселов на единичном отрезке ($density)
	-R, --radius ⟨вещественное число⟩
		радиус ($radius)
	-h, --help
		показать эту подсказку
__HELP__
	exit;
}

Следующим шагом будет извлечение опций из командной строки:

Perl
GetOptions
	(
		'o|output-file=s'	=>\$outputFile,
		'r|region=s'		=>\$region,
		'd|density=f'		=>\$density,
		'R|radius=f'		=>\$radius,
		'h|help'			=>\&help,
	);

Теперь извлечём из значения опции --region отдельные числовые компоненты при помощи split и разместим их в четырёх переменных с говорящими именами:

Perl
my ($left, $bottom, $right, $top)=split ':', $region;

Нам будет удобнее оперировать не с радиусом, а с его квадратом, поэтому будет разумным вычислить этот квадрат:

Perl
my $squaredRadius=$radius**2;

После всех этих приготовлений можно приступать к содержательной части программы.

Ключевой в программе будет процедура iterate, которая по двум вещественным числам $u$ и $v$ определяет цвет, которым должна быть закрашена точка $w=u+iv$. Как и планировалось, мы применяем метод Флойда. Черепаха, заданная как пара переменных $tx и $ty, побежит по орбите. Заяц тоже, но с удвоенной скоростью. Остановится цикл в одном из двух случаев: либо черепаха выйдет за пределы круга радиуса $R$, либо Черепаха и Заяц сблизятся на расстояние, меньшее чем $\frac{1}{R}$. От этого будет зависеть знак возвращаемого процедурой значения. Разумеется, с каждым проходом цикла должна увеличиваться переменная $n, подсчитывающая длину черепашьей орбиты. Эта длина также используется для нахождения цвета:

Perl
sub iterate($$)
{
	my ($u, $v)=@_;
	my ($tx, $ty)=my ($hx, $hy)=(0, 0);
	my $n=0;
	while()
	{
		($tx, $ty)=($tx**2-$ty**2+$u, 2*$tx*$ty+$v);
		($hx, $hy)=($hx**2-$hy**2+$u, 2*$hx*$hy+$v) for 0, 1;
		return 1/sqrt($n/4+1) if $tx**2+$ty**2>=$squaredRadius;
		return -1/sqrt($n/4+1) if (($tx-$hx)**2+($ty-$hy)**2)*$squaredRadius<1;
		$n++;
	}
}

Настало время создать графический файл. При создании потребуется указать размеры изображения в пикселах. Для нахождения размеров нужно взять целую часть каждого из размеров прямоугольника на комплексной плоскости, умноженного на величину $density.

Perl
my ($w, $h)=map { int($density*$_) } ($right-$left, $top-$bottom);

Теперь в переменных $w и $h оказались ширина и высота изображения в пикселах. Можно создавать новое, пока ещё целиком чёрное изображение, применяя методы из класса Image::Magick:

Perl
my $image=Image::Magick->new(size=>"${w}x$h");
$image->ReadImage('NULL:black');
$image->Color(color=>'black');
$image->Comment("region=$region density=$density radius=$radius");
$image->Set(depth=>8);

Вторая и третья строчки выглядят как некая чёрная магия. Без второй изображение не удаётся сохранить в файле. Без третьей изображение сохраняется, но оказывается полностью прозрачным. Не ломая голову над смыслом этих двух команд, мы позаимствовали их из многочисленных примеров, размещённых на сайте проекта ImageMagick. Программа заработала, и, как говорится, слава богу.

Метод Comment прикладывает к изображению текстовый комментарий. Мы воспользовались этой возможностью, чтобы вместе с картинкой сохранить значения важных опций, использовавшихся при создании изображения.

Наконец, метод Set позволяет устанавливать различные свойства изображения. Мы устанавливаем свойство depth (глубину). Глубиной изображения называют количество бит на один пиксел. Количество различных цветовых значений, которые может принимать пиксел, можно получить, возведя двойку в степень, равную глубине. Стандартным значением глубины для формата PNG является 24 бита (TrueColor), то есть по 8 бит на каждую цветовую компоненту — красную, зелёную и синюю. Мы же выбрали глубину в восемь бит, надеясь, и не без оснований, уменьшить размер получившегося графического файла.

В режиме TrueColor каждый пиксел изображения кодируется как три байта, где в каждом байте записана интенсивность красной, зелёной и синей компоненты. При глубине 8 применяется другой подход. К изображению прилагается массив (палитра), в котором перечислены все использованные цвета в 24-битном формате. Этих цветов не более 256, так что размер палитры получается небольшим (максимум 768 байт). Каждый пиксел изображения при этом кодируется как восьмибитный номер цвета из палитры. Этот режим называется Palette, или индексированным.

Может показаться, что размер файла при восьмибитной глубине уменьшается втрое, но это не так. Растровые изображения обычно подвергаются сжатию, из-за чего экономия может отличаться от трёхкратной. Кроме того, графический файл может содержать вспомогательную информацию: палитру, комментарии, сведения о программном обеспечении, использованном при создании, и всякое другое.

Разумеется, уменьшение глубины делает картинку более бедной: вместо $16777216$ возможных цветов придётся обойтись лишь $\mathrm{256}$. Но особенность нашей задачи такова, что уменьшение количества цветов остаётся незаметным для невооружённого глаза. Чтобы читатель мог самостоятельно оценить влияние глубины на качество картинки и размер файла, мы предлагаем рисунок 48.3. «Растровое изображение в режимах TrueColor и Palette» нашей любимой железобетонной роншанской капеллы Нотр-дам-дю-о. Левое изображение закодировано в режиме TrueColor и весит 106553 байта, а правое — в режиме Palette (31499 байт).

Рисунок 48.3. Растровое изображение в режимах TrueColor и Palette

Perl
for my $i(0..$w-1)
{
	printf "\e[K\rГотово: \%d\%\%", $i/$w*100;
	STDOUT->flush;
	for my $j(0..$h-1)
	{
		вычислить $color
		$image->SetPixel(x=>$i, y=>$j, color=>$color);
	}
}

Perl
my $value=iterate($i/$density+$left, -$j/$density+$top);
my $color=$value<0? [-$value, 0, 0]: [0, $value, 0];

Perl
my $jConjugate=2*$density*$top-$j;
my $color;

Perl
if($jConjugate<$j and $jConjugate>=0)
{
	$color=[$image->GetPixel(x=>$i, y=>$jConjugate)];
}
else
{
	my $value=iterate($i/$density+$left, -$j/$density+$top);
	$color=$value<0? [-$value, 0, 0]: [0, $value, 0];
}

Perl
if((my $message=$image->Write($outputFile)) eq '')
{
	my $size=-s $outputFile;
	print "\e[K\rФайл «$outputFile» (${w}×$h, $size байт) записан.\n";
}
else
{
	die "\n$message\n";
}